KISSSOFT 03/2018安裝問題請教各位大大

zengxiaodong

zengxiaodong

@echo OFF & CLS & ECHO.

:: BatchGotAdmin
:: https://social.technet.microsoft ... rum=w7itprosecurity
:-------------------------------------
REM  --> Check for permissions
NET FILE 1>NUL 2>NUL &

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
    pushd "%CD%"
    CD /D "%~dp0"
:--------------------------------------  

REM ... proceed here with admin rights ...

IF EXIST "%~dp0\opengl32.dll" (
    CHOICE /M "Software OpenGL driver is already enabled. Do you want to disable it?"
    IF ERRORLEVEL 2 GOTO End
    IF ERRORLEVEL 1 (
        DEL "%~dp0\opengl32.dll"
        IF ERRORLEVEL 1 (
            ECHO Failed to disable Software OpenGL driver. Please contact KISSsoft support for assistance.
        ) ELSE (
            ECHO Software OpenGL driver disabled succesfully!
        )
    )
) ELSE (
    COPY "%~dp0\opengl32sw.dll" "%~dp0\opengl32.dll" >nul 2>&1
    IF ERRORLEVEL 1 (
       ECHO Failed to enable Software OpenGL driver. Please contact KISSsoft support for assistance.
    ) ELSE (
        ECHO Software OpenGL driver enabled succesfully!
    )
)

:End
@PAUSE

zengxiaodong

Caizhiming0709 发表于 2019-4-10 19:33
各位大大們晚安,謝謝曾經看過帖子的大大們,我很好奇各位有安裝kisssoft 03 2018的大大們沒有人用的系統是WI ...

其实这个问题在2017版就开始出现了，很多电脑由于运行不了2017版的Kisssoft都无奈退回到2016版，所以2017这个版本非常少的人使用，就像不存在这个版本似的。


此后，2018版出来了，似乎问题没有2017版那么普遍，估计主要的原因是旧电脑占比的下降而已......

一直到今天的2022版，仍然存在显卡OpenGL的驱动问题，所以在年代越久远的电脑上，越容易出现不兼容的问题，Kisssoft公司也早就发布了关于如何处理这个问题的内部文件。

opengl.pdf (172.4 KB, 下载次数: 14)

2023-1-10 08:29 上传

点击文件名下载附件

zengxiaodong

终于找到这个帖子

EnableSoftwareOpenGL.bat